RsL est une Source de Données
Sql est une chaîne
Df est une Description de Fichier
Dr est une Description de Rubrique
sFicFacture est une chaîne = "CLICDEH"	//Nom du fichier Facture
sFicLigne est une chaîne = "CLICDEL"    //Nom du fichier ligne de facture
sFicStat est une chaîne = "STAT1"       //Nom du fichier temporaire pour statistique mensuelle
sDateDebut est une chaîne = "20030101"  //Date début stat
sDateFin est une chaîne = "20031231"	//Date fin Stat
sRubriqueParcours est une chaîne = "DatePiece" //Nom de la rubrique de parcours sur fichier facture   
sRubIdArticle est une chaîne = "GUIARTICLE" //Nom de rubrique Identifiant Article Idem au Fichier facture
sCleParcours est une chaîne		//Va contenir la clé de parcours la mieux adaptée	
sIdFacture est une chaîne = "NumeroDePiece" //Nom de la rubrique Id de Facture lier et de meme nom que dans Ligne de facture
sRubARenvoyer est une chaîne = "MontantTotalHT" //Nom de la rubrique qui contient la valeur à calculer
tMois est une chaîne = "Janvier,Fevrier,Mars,Avril,Mai,Juin,Juillet,Aout,Septembre,Octobre,Novembre,Decembre"
sUnMois est une chaîne
Ind est un entier

nMNTVente est un réel

Sablier(Vrai)
//Description dynamique du fichier
//Si vous ne voulez pas modifier votre analyse.
Df..Nom = sFicStat
Df..Type = hFichierTemporaire

//Description de la rubrique IDStat
Dr..Nom = "IDStat"
Dr..Type = hRubIdAuto
Dr..TypeClé = hCléUnique
HDécritRubrique(Df,Dr)

//Description de la rubrique IDArticle
Dr..Nom = sRubIdArticle
Dr..Type =hRubEntier8
Dr..TypeClé = hCléUnique
HDécritRubrique(Df,Dr)

//Description des rubriques mois
Ind = 1
sUnMois = ExtraitChaîne(tMois,Ind,",")

TANTQUE sUnMois <> EOT
	Dr..Nom = sUnMois
	Dr..Type =hRubMonétaire
	HDécritRubrique(Df,Dr)
	Ind++
	sUnMois =	ExtraitChaîne(tMois,Ind,",")
FIN

HDécritFichier(Df)

//Création du fichier
HChangeRep(sFicStat,fRepEnCours())
HCréation(sFicStat)

//Creation de la vue 
HCréeVue(RsL,sFicStat,"*",hVueBlocage)

//Création du filtre sur le fichier Facture
sCleParcours = HFiltreComprisEntre(sFicFacture,sRubriqueParcours,sDateDebut,hSéparateurBorne,sDateFin)
//Parcours du fichier
HLitPremier(sFicFacture,sCleParcours,hBlocageNon)
TANTQUE PAS HEnDehors()
	//Recherche par IdFacture
	HLitRecherche(sFicLigne,sIdFacture,{sFicFacture+"."+sIdFacture},hBlocageNon)
	nMNTVente=0
	TANTQUE HTrouve(sFicLigne)	
			nMNTVente+={sFicLigne+"."+sRubARenvoyer}	
			HLitSuivant(sFicLigne,sIdFacture)
	FIN
	Ind = Val({sFicFacture+"."+sRubriqueParcours}[[5 A 6]])
	//Recherche si l'Article à déjà éte Créé
	SI PAS HLitRecherche(RsL,sRubIdArticle,{sFicLigne+"."+sRubIdArticle}) ALORS
		{"Rsl."+sRubIdArticle} = {sFicLigne+"."+sRubIdArticle}
		{"Rsl."+ExtraitChaîne(tMois,Ind,",")}+= nMNTVente
		SI PAS HAjoute(RsL,hIgnoreIntégrité+hIgnoreDoublon) ALORS
			Erreur(HErreurInfo())
		  STOP
		FIN
	SINON
		{"Rsl."+ExtraitChaîne(tMois,Ind,",")} = nMNTVente
		SI PAS HModifie(RsL,hNumEnrEnCours,hIgnoreIntégrité+hIgnoreDoublon) ALORS
			Erreur(HErreurInfo())
			STOP
		FIN
	FIN
		
	HLitSuivant(sFicFacture,sCleParcours)
FIN
HVueVersFichier(RsL)
Sablier(Faux)

ConstruitTableFichier(Table,RsL,taSansMémoImage+taSansMémoTexte+taLibelléRubrique+taRemplirTable)

sFicFacture est une chaîne = "CLICDEH"	//Nom du fichier Facture
sFicLigne est une chaîne = "CLICDEL"    //Nom du fichier ligne de facture
sFicStat est une chaîne = "STAT1"       //Nom du fichier temporaire pour statistique mensuelle
sDateDebut est une chaîne = "20030101"  //Date début stat
sDateFin est une chaîne = "20031231"	//Date fin Stat
sRubriqueParcours est une chaîne = "DatePiece" //Nom de la rubrique de parcours sur fichier facture   
sRubIdArticle est une chaîne = "GUIARTICLE" //Nom de rubrique Identifiant Article Idem au Fichier facture
sIdFacture est une chaîne = "NumeroDePiece" //Nom de la rubrique Id de Facture lier et de meme nom que dans Ligne de facture
sRubARenvoyer est une chaîne = "MontantTotalHT" //Nom de la rubrique qui contient la valeur à calculer