|
Envoi mail en prog |
|
Stagiaire WDF
Inscrit: 28/09/2005 19:26
Post(s): 7
|
Bonjour
je galère pour envoyer un mail automatique en fin de programme pour me faire un compte rendu.
Je suis sur un domaine W2000 Server. Un serveur exchange 5.5. un CLient outlook 2003 sur mon PC.
Donc je veux envoyer un mail sur plusieurs boites dont la mienne depuis mon poste qui reste allumé la nuit et qui execute des taches.
Post posé sur pcosft mais sans réponse concluante pour moi.
help me. merci pour vos contributions.
Ca me surprend, car sous Access, je fais un truc tout simple qui marche super bien. code ci dessous.
//// Public Sub EnvoiMailAutomatique(ByVal pTo As String, ByVal pSubject As String, ByVal pBody As String) Dim wOutlook As Object Dim wMail As Object ' On crée une instance d'Outlook : Set wOutlook = CreateObject("Outlook.Application") ' Et on crée un élément Outlook, qui sera un message E-Mail : Set wMail = wOutlook.CreateItem(0) wMail.To = pTo wMail.Subject = pSubject wMail.Body = pBody wMail.send Set wOutlook = Nothing End Sub ///
Contribution le : 24/05/2006 16:16
|
|
|
Re: Envoi mail en prog |
|
Animateur WDF
Inscrit: 02/03/2003 04:07
De Noisy le grand(93)
Post(s): 2745
|
Bonjour,
PROCEDURE EnvoiMailAutomatique(pTo , pSubject , pBody )
wOutlook est un objet automation dynamique
wMail est un objet automation dynamique
// On crée une instance d'Outlook :
wOutlook = Allouer un objet automation "Outlook.Application"
//Et on crée un élément Outlook, qui sera un message E-Mail :
wMail = wOutlook>>CreateItem(0)
wMail>>To = pTo
wMail>>Subject = pSubject
wMail>>Body = pBody
wMail>>send()
liberer wOutlook
Contribution le : 24/05/2006 23:32
|
|
|
Re: Envoi mail en prog |
|
Anonyme
|
Merci,cela fonctionne.
dernier point. je voudrais rajouter la possibilité de joindre une pièce jointe.
Comment faire? et comment savoir les méthodes et propriétés des objets mail ou outlook crées?
merci bcp
Contribution le : 29/05/2006 08:10
|
|
|
Re: Envoi mail en prog |
|
Stagiaire WDF
Inscrit: 13/04/2005 13:54
Post(s): 32
|
Bonjour, Un exemple de code avec pièce jointe. Pour trouver les informations sur les propriétés et méthodes des objets outlook il suffit d'ouvrir l'éditeur Visual Basic d'Outlook (F11) et de rechercher dans l'explorateur d'objets. // Description des paramètres d'entrée/sortie de 'EnvoiMessage' :
//
// Syntaxe :
//EnvoiMessage ([<P_Nomrep>[, <P_NomFic>[, <P_Sujet>[, <P_Texte>[, <P_Destinataire>[, <P_Envoyer>]]]]]])
//
// Paramètres :
// P_Nomrep : <Nom du répertoire contenant les fichiers joints avec ou sans "\" final>
// P_NomFic : <Nom du fichier (sans le chemin)>
// P_Sujet : <Sujet du message>
// P_Texte : <Texte du message>
// P_Destinataire : <Destinataire>
// P_Envoyer : <Vrai si l'envoi est automatique sans affichage>
// Valeur de retour :
// Aucune
// Notes :
// Cette méthode permet d'envoyer un message avec ou sans fichiers joints
// tous les Paramètres sont facultatifs
//
// Exemple :
// Indiquez ici un exemple d'utilisation.
//
FONCTION GLOBALE Outils::EnvoiMessage( P_Nomrep="",P_NomFic="",P_Sujet="", P_Texte="",P_Destinataire="",P_Envoyer=Faux)
L_Ch est chaîne // Nom des fichiers joints pour message
L_Outlook est un objet OLE dynamique // Objet Outlook
L_Message est un objet OLE dynamique // Objet message
L_Attachement est un objet OLE dynamique // Objet fichiers joints
L_Taille est entier // Taille du texte de message
L_Selection est booléen=Vrai // Résultat ouverture Outlook
L_NomRech est chaîne // Nom pour recherche dans répertoire
// la page a été trouvée
L_Outlook=ObjetActif("Outlook.Application")
SI L_Outlook=Null ALORS
// lancement Outlook
L_Outlook=allouer un objet Automation "OutLook.Application"
SI L_Outlook=Null ALORS
Erreur("Ouverture de Outlook Impossible")
L_Selection=Faux
FIN
FIN
// outlook est ouvert
SI L_Selection ALORS
L_Message=L_Outlook>>CreateItem(0)
L_Message>>Subject=P_Sujet
L_Message>>to=P_Destinataire
L_Message>>Body=P_Texte+RC
L_Taille=Taille(P_Texte)
// Traitement des fichiers joints
SI SansEspace(P_Nomrep)<>"" ALORS
L_Attachement=L_Message>>Attachments
SI SansEspace(P_NomFic)<>"" ALORS
L_NomRech=ComplèteRep(P_Nomrep)+P_NomFic
SINON
L_NomRech=ComplèteRep(P_Nomrep)+"*.*"
FIN
L_Ch=fRep(L_NomRech,frFichier)
// Ajout des fichiers joints
TANTQUE L_Ch<>""
L_Attachement>>Add(ComplèteRep(P_Nomrep)+L_Ch,1)
L_Ch=fRep("")
FIN // Fin de boucle attachements
FIN
SI P_Envoyer ET PAS EnModeTest() ALORS
L_Message>>Send()
SINON
L_Message>>Display()
FIN
// Libération des objets Outlook
SI SansEspace(P_Nomrep)<>"" ALORS
libérer L_Attachement
FIN
libérer L_Message
libérer L_Outlook
FIN
Contribution le : 29/05/2006 08:26
|
|
|
Re: Envoi mail en prog |
|
Stagiaire WDF
Inscrit: 28/09/2005 19:26
Post(s): 7
|
merci bcp à tout les deux
LostIn
Contribution le : 29/05/2006 08:41
|
|
Vous ne pouvez pas débuter de nouveaux sujets.
Vous pouvez voir les sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.