Bonjour,

Dans une fenêtre j'ai un bouton actualiser qui me permet de remplir 2 tables et aussi de remplir 2 champ Images par des graphes en fonction de la table numéro 1.

J'ai donc créé 4 procédures locales : 1 pour chaque Tables et 1 pour chaque champ Image.

POur les tables tout fonctionne sans probléme.

Par contre pour les graphes:

SI je mets les procédures dans le bouton actualiser dans l'ordre suivant :
remplir Image 1
remplir Image 2

J'ai uniquement le graphe de l'image 2 qui apparait.

Par contre si je fais l'inverse:

remplir Image 2
remplir Image 1

J'ai uniquement le graphe de l'image 1 qui apparait.


N'arrivant pas à trouver de solution, voici le code de mes procédures :

PROCEDURE RemplirImage2()

sNomGraphe1 est une chaîne = "GRP_STAT"

// Suppression de l'ancien graphe
SI grExiste(sNomGraphe1) = Vrai ALORS
grSupprimeTout(sNomGraphe1)
FIN

// Définition du graphique
i est un entier

// Création du graphe
grCrée(sNomGraphe1, grSecteur)

// Destination du graphe
grDestinationChamp(sNomGraphe1, Image2)
grLégende(sNomGraphe1,grADroite)
grLibellé(sNomGraphe1,grAffichePourcentage,Vrai)
grSecteurPartExcentrée(sNomGraphe1,3,25)

// Libellé des catégories
grEtiquetteCatégorie(sNomGraphe1,1, "MEUBLES")
grEtiquetteCatégorie(sNomGraphe1,2, "SOMMIERS / MATELAS")
grEtiquetteCatégorie(sNomGraphe1,3," ELECTROMENAGERS")
grEtiquetteCatégorie(sNomGraphe1,4,"DIVERS")

grEtiquetteSérie(sNomGraphe1,1,"Encombrants")


// Mise a jour des couleurs

//grCouleurSérie(snomgraphe,1,iRougeclair)
//grCouleurSérie(snomgraphe,2,irougefoncé)
//grCouleurSérie(snomgraphe,3,icyanClair)
//grCouleurSérie(snomgraphe,4,iVertClair)

// Titre du graphe
grPoliceTitre(sNomGraphe1,PoliceCrée("Trebuchet MS",12,iGras,iGrisFoncé))
grTitre(sNomGraphe1, "Répartitions des Encombrants")

// Afficher les bulles d'aide
grBulle(sNomGraphe1, grBulleActive, Vrai)

// Ajout des données
POUR i=1 A TableOccurrence(Table1)
// On affecte selon les mêmes critères que la table

SELON Table1.COL_MEUBLES[i]
CAS = Vrai :
// meubles => couleur bleu
grIncrémenteDonnée(sNomGraphe1,1, 1,1)
FIN
SELON Table1.COL_LIT[i]
CAS = Vrai
// lits => couleur violet
grIncrémenteDonnée(sNomGraphe1,1, 2,1)
FIN
SELON Table1.COL_ELECTRO[i]
CAS = Vrai :
// Electroménagers => couleur orange
grIncrémenteDonnée(sNomGraphe1,1, 3,1)
FIN
SELON Table1.COL_DIVERS[i]
CAS = Vrai :
// Divers => couleur vert
grIncrémenteDonnée(sNomGraphe1,1, 4,1)
FIN

FIN

// Dessin du graphe
grDessine(sNomGraphe1)

Pour l'image 1, j'ai juste remplacé les Image2 par Image1

Il ne faut pas utiliser le même nom de graphe pour les 2 images.
Le 1er graphe est tracé "en mémoire" dans la zone sNomGraphe1.
Puis vous l'effacer pour tracer le second. Il est normal qu'il n'y ai plus rien sur le premier.
solution
sNomGraphe1 est une chaîne = "GRP_STAT1" pour le 1er graphe
sNomGraphe1 est une chaîne = "GRP_STAT2" pour le 2eme graphe

Bon Dev

C'est exactement cela, j'ai eu ce souci une fois et le fait de gérer dans ta procédure le nom du graphe en fonction de l'image devrait résoudre ton problème !!!

Le plus simple est de paramétré le nom de ton graph en début de procédure et de l'attribué dans une variable CHAINE!!!

Dans les variables de te procédure en appel tu mets le nom du champ de destination du graph !!!

sNomGraph est une chaine

Selon NomImgDest
cas ImgImage1..nom :
sNomGraph = "Graph1"
cas ImgImage2..nom :
sNomGraph = "Graph2"
FIN


j'espère avoir été assez clair dans mon explication afin de t'aider au mieux !!!


Bon dev.

Merci à vous, j'ai juste modifier les GRP_STAT en les différenciant et tout foncitonne

Merci encore

Comme quoi des fois, c'est tout bête !!!

Tu as raison, il suffit juste d'y penser ;)