Bonjour.

Voici le code que j'ai mis en place pour création d'une archive .zip ou .wdz et ça ne me remplit pas l'archive et me renvoit le message : "le chemin fourni n'est pas valide".

Je ne comprends vraiment pas pourquoi.


//Déclaration et initialisation des variables
NomArchive est une chaîne = "Sauvegarde.zip"
CheminArchive est une chaîne
ListeFichier est une chaîne
ResCréationArchive est un entier
NbFichier est un entier

// Sélection du chemin de l'archive
CheminArchive = fRepSélecteur("", "Sélection du répertoire", "Sélection du dossier où placer l'archive")
// Vérification du chemin et recherche d'erreur
SI CheminArchive <> "" ALORS
Info("Le répertoire sélectionné est : "+CheminArchive)
SINON
// Affichage du message d'erreur
Erreur(ErreurInfo(errMessage))
FIN

// Création de l'archive "NomArchive"
ResCréationArchive = zipCrée(NomArchive, ComplèteRep(CheminArchive)+NomArchive)

// Ajout de fichiers si l'archive a été créée
SI ResCréationArchive = 0 ALORS
Info("L'archive est : "+NomArchive) //vérification du renvoi, à suppr après validation test
Info("Son chemin est : "+CheminArchive) //idem
// Ajout des fichiers dans l'archive
ResCréationArchive = zipAjouteListeFichier(NomArchive,"*.fic"+RC+"*.ndx"+RC+"*.mmo")
FIN
// Affichage du message d'erreur si les fichiers n'ont pas été ajoutés
SI ResCréationArchive <> 0 ALORS
Erreur(zipMsgErreur(ResCréationArchive))
FIN

// Liste des fichiers de l'archive
ListeFichier = zipListeFichier(NomArchive) //vérification du renvoi, à suppr après validation test

// Nombre de fichiers contenus dans l'archive
NbFichier = zipNbFichier(NomArchive) //vérification du renvoi, à suppr après validation test

zipFerme(NomArchive)
Info("Sauvegarde terminée")

Merci

A quel stade intervient l'erreur ?

A Erreur(ErreurInfo(errMessage)) ou a Erreur(zipMsgErreur(ResCréationArchive)) ?

(Je n'ai pas Windev pour tester ici ...)

Si tu es sous vista, vérifie que tu n'essayes pas d'enregistrer a la racine de C:, ca marche pas. Pour avoir un chemin ou tu es sur de pouvoir sauvegarder : C:\Documents And Settings(Users sous Vista)\TonNomD'UtilisateurEnCours\Application Data\UnDossierDeTonChoix(N'oublie pas de le créer ;) )\

PS : Utilise une des variables utilisateurs de windev qui te renverra le chemin utilisateur.

Bonsoir Dream_Team

Erreur(zipMsgErreur(ResCréationArchive))
Ca me crée bien l'archive, mais ne la remplit pas.
L'erreur vient donc des paramètres de zipAjouteListeFichier.

Je vais voir du côté des variables; merci.

Apparemment zipAjouteListeFichier est trompeur. Il ne scan pas comme fListe fichier il prends juste tous les fichiers en parametre.

Comme vous etes en Widev 11, vous avez acces a la nouvelle syntaxe de fListeFichier.

Voila donc votre code corrigé :

//Déclaration et initialisation des variables
NomArchive est une chaîne = "Sauvegarde.zip"
CheminArchive est une chaîne
ListeFichier est une chaîne
ResCréationArchive est un entier
NbFichier est un entier
ErreurPrésente est un booléen = Faux

// Sélection du chemin de l'archive
CheminArchive = fRepSélecteur("", "Sélection du répertoire", "Sélection du dossier où placer l'archive")
// Vérification du chemin et recherche d'erreur
SI CheminArchive <> "" ALORS
Info("Le répertoire sélectionné est : "+CheminArchive)
SINON
// Affichage du message d'erreur
Erreur(ErreurInfo(errMessage))
FIN

// Création de l'archive "NomArchive"
ResCréationArchive = zipCrée(NomArchive, ComplèteRep(CheminArchive)+NomArchive)

// Ajout de fichiers si l'archive a été créée
SI ResCréationArchive = 0 ALORS
Info("L'archive est : "+NomArchive) //vérification du renvoi, à suppr après validation test
Info("Son chemin est : "+CheminArchive) //idem
// Ajout des fichiers dans l'archive
ListeFichier = fListeFichier("*.fic")
ResCréationArchive = zipAjouteListeFichier(NomArchive,ListeFichier)
SI ResCréationArchive <> 0 ALORS ErreurPrésente = Vrai
ListeFichier = fListeFichier("*.ndx")
ResCréationArchive = zipAjouteListeFichier(NomArchive,ListeFichier)
SI ResCréationArchive <> 0 ALORS ErreurPrésente = Vrai
ListeFichier = fListeFichier("*.mmo")
ResCréationArchive = zipAjouteListeFichier(NomArchive,ListeFichier)
SI ResCréationArchive <> 0 ALORS ErreurPrésente = Vrai
ListeFichier = "" // On nettoie apres notre passage
FIN
// Affichage du message d'erreur si les fichiers n'ont pas été ajoutés
SI ErreurPrésente ALORS
Erreur(zipMsgErreur(ResCréationArchive))
FIN

// Liste des fichiers de l'archive
ListeFichier = zipListeFichier(NomArchive) //vérification du renvoi, à suppr après validation test

// Nombre de fichiers contenus dans l'archive
NbFichier = zipNbFichier(NomArchive) //vérification du renvoi, à suppr après validation test
zipFerme(NomArchive)
Info("Sauvegarde terminée")

Bonjour,

ça fonctionne, super !

depuis, j'avais constaté que de toute façon zipAjouteListeFichier ne pouvat fonctionner, n'acceptant pas les caractères joker.

merci 1000 fois